;* ====================================================== *
;* 华信单片机工作室 卢先生 http://www.hx51.com msktlch@126.com
;* 整理验证日期: 2002/09/23
;----------------------------------------------------------
;* 标题：点钞机外接显示屏，程序名：File = WJD961_4.ASM
;* 描述: 采用AT89C2051芯片,晶振频率:11.0592MHz。
;* 初始状态数码管个位显示"0",最大计数范围: 999。
;* =======================================================*
LED1 BIT P3.5 ;百位(定义数码管公共端)
LED2 BIT P3.4 ;十位
LED3 BIT P3.7 ;个位
JSQ0 DATA 50H ;脉冲计数单元高字节
JSQ1 DATA 51H ;脉冲计数单元低字节
LED01 DATA 3AH ;显示段码缓存器(百位)
LED02 DATA 3BH ;十位
LED03 DATA 3CH ;个位
R31 DATA 1FH
;* =======================================================*
ORG 0000H
AJMP START ;复位转主程序
ORG 0003H ;INT0的入口地址
AJMP INT0_P32
;* ------------------------------------------------------ *
; 主程序0030H单元开始
;* ------------------------------------------------------ *
ORG 0030H ;跳过中断向量区
START: MOV R0,#7FH
CLR A
DEL1: MOV @R0,A ;预使用单元清0
DJNZ R0,DEL1
MAIN: MOV SP,#60H ;60H为栈顶位置初值
SETB IT0 ;置INT0为边沿触发方式
MOV IP,#00000001B ;置INT0为高优先级中断
MOV IE,#10000001B ;INT0开中
MOV JSQ0,#0 ;计数单元清0
MOV JSQ1,#0
CLR P1.0 ;注意在软件模拟调试时,P1.0由于没有接外部上拉电阻,
;拉低后就无法拉高.为了调试方便可选取89C51进调试
;*--------------------------------------------------------*
DIR0_0:JB P1.0,DIR0_01 ;当点钞机已复位,但未放入纸币,所以未中断
MOV R31,#28
ACALL DELAY2 ;延时1ms,去抖动
JB P1.0,DIR0_01
SETB P1.0
MOV JSQ0,#0 ;复位信正确,计数单元清0
MOV JSQ1,#0
ACALL HB2 ;将16进制数转换为BCD码
ACALL THIF0 ;调用转换显示值子程序
DIR0_01:
MOV A,LED01 ;当十位,百位数=0时,将其屏蔽
CJNE A,#81H,DIR0_02
MOV LED01,#0FFH
MOV A,LED02
CJNE A,#81H,DIR0_02
MOV LED02,#0FFH
DIR0_02:
SETB LED1 ;LED1位显示停
MOV P1,LED03 ;读个位段码
CLR LED3 ;LED1个位显示
MOV R31,#42
ACALL DELAY2 ;延时2ms
SETB LED3 ;LED1位显示停
MOV P1,LED02 ;读十位段码
CLR LED2 ;LED2十位显示
MOV R31,#42
ACALL DELAY2
SETB LED2 ;LED2十位显示停
MOV P1,LED01 ;读百位段码
CLR LED1 ;LED1百位显示
MOV R31,#42
ACALL DELAY2
AJMP DIR0_0 ;不断循环显示,并等待中断
;* =======================================================*
;计数复位时,点钞机主程序会先给出一个复位信号,并持续一段时间,
;接着给出计数脉冲
INT0_P32:
PUSH ACC ;保护现场
PUSH DPH
PUSH DPL
JB P1.0,INT0_01 ;当点钞机
MOV R31,#28
ACALL DELAY2 ;延时1ms,去抖动
JB P1.0,INT0_01
SETB P1.0 ;清除复位信号
MOV JSQ0,#0 ;复位信正确,计数单元清0
MOV JSQ1,#0
INT0_01:
MOV A,JSQ1 ;低字节计数单元加1
INC A
MOV JSQ1,A
JNZ INT0_02
INC JSQ0 ;当有进位时,高字节单元加1
INT0_02:
ACALL HB2 ;将16进制数转换为BCD码
ACALL THIF0 ;调用转换显示值子程序
POP DPL ;恢复现场
POP DPH
POP ACC
RETI ;中断返回
;* =======================================================*
;* 双字节十六进制整数转换成双字节ＢＣＤ码整数
;入口条件：待转换的双字节十六进制整数在R6、R7中。
;出口信息：转换后的三字节ＢＣＤ码整数在R3、R4、R5中。
;影响资源：PSW、A、R2～R7堆栈需求： ２字节
;* =======================================================*
HB2:
MOV R6,JSQ0 ;高字节单元送入R6
MOV R7,JSQ1 ;低字节单元送入R7
CLR A ;BCD码初始化
MOV R3,A
MOV R4,A
MOV R5,A
MOV R2,#10H ;转换双字节十六进制整数
HB3:
MOV A,R7 ;从高端移出待转换数的一位到CY中
RLC A
MOV R7,A
MOV A,R6
RLC A
MOV R6,A
MOV A,R5 ;BCD码带进位自身相加,相当于乘2
ADDC A,R5
DA A ;十进制调整
MOV R5,A
MOV A,R4
ADDC A,R4
DA A
MOV R4,A
MOV A,R3
ADDC A,R3
MOV R3,A ;双字节十六进制数的万位数不超过6,不用调整
DJNZ R2,HB3 ;处理完16bit
RET
;* =======================================================*
;* 将BCD码解压后,转换为十进制显示符
;* =======================================================*
THIF0: ;将压缩BCD码解压(因最大数为999,所以[R3]=0)
MOV A,R5 ;取数据
ANL A,#0FH ;屏蔽高4位,取出低4位
MOV 32H,A ;存个位
MOV A,R5
SWAP A ;交换
ANL A,#0FH
MOV 31H,A ;存十位
MOV A,R4 ;取数据
ANL A,#0FH ;屏蔽高4位,取出低4位
MOV 30H,A ;存百位
;* 将BCD转换为十进制显示符
MOV DPTR,#TABD ;置数码表首址
MOV R0,#30H ;置显示数首址
MOV R1,#LED01 ;置字段码暂存器首址
MOV R2,#03H ;置循环数
THIF1:
MOV A,@R0 ;取显示数
MOVC A,@A+DPTR ;读字段码
MOV @R1,A ;存字段码
INC R0 ;修改显示数地址
INC R1 ;修改字段码暂存器地址
DJNZ R2,THIF1 ;判断循环是否结束
RET
TABD:
DB 81H,0EDH,43H,49H,2DH,19H ;共阳字段表,0～5显示符
DB 11H,0CDH,01H,09H ;6～9显示符
;* =======================================================*
;* 延时子程序
DELAY2:
L2: PUSH R31
L3: DJNZ R31,L3
POP R31
DJNZ R31,L2
RET
END
;* =======================================================*